\ Picture words give a flag based on x and y.
0 Value x  0 Value y  \ 10000x fixed decimal.
 
: from ( nn-n) swap - ;
: sq ( n-n) dup 10000 */ ;
: disc ( rxy-f) y from sq swap x from sq + > ;
: udisc ( -f) 10000 0 0 disc ;
 
: vert ( -f) x -1500 -6000 within ;
: horz ( -f) y -2000 -4000 within ;
: smash ( -f) udisc vert and horz and ;
 
: pair ( r-ff) dup 0 5000 disc swap 0 -5000 disc ;
: wave ( -f) 2500 pair invert x 0< and or ;
: eyes ( -f) 278 pair or ;
: yinyang ( -f) udisc wave xor eyes xor ;
 
: pit ( -f) x 7143 1429 within y 1429 < or ;
: pit+ ( f-f) pit and  x negate y to x to y ;
: manji ( -f) true pit+ pit+ pit+ pit+ ;
 
 
\ Emit UTF-8 for Braille U+28XX, given XX.
: emitb8 ( c-) ?dup-0=-IF $80 THEN  $E2 emit
  dup 6 rshift $A0 or emit  $3F and $80 or emit ;
 
: ~ c, ;     \ Dot row/col per Braille bit:  0 3
: CVals ( -;i-c) Create does> + c@ ;      \  1 4
CVals dr 0 ~ 1 ~ 2 ~ 0 ~ 1 ~ 2 ~ 3 ~ 3 ~  \  2 5
CVals dc 0 ~ 0 ~ 0 ~ 1 ~ 1 ~ 1 ~ 0 ~ 1 ~  \  6 7
 
\ Screen row/col/dot to pic x/y, -10000 to 10000.
0 Value r  0 Value c  0 Value d  Defer pic ( -f)
12 dup Constant hgt  2* Constant wid
: toy ( -) r 4 * d dr + -5000 hgt */ 10000 + to y ;
: tox ( -) c 2 * d dc + 10000 wid */ 10000 - to x ;
: dotbit ( -c) toy tox pic 1 and d lshift ;
: calcb8 ( -c) 0 8 0 DO i to d dotbit or LOOP ;
: line ( -) wid 0 DO i to c calcb8 emitb8 LOOP ;
: draw ( -) hgt 0 DO i to r cr line LOOP ;
\ ' smash is pic draw
 
: 3pic ( -xxx) ['] smash ['] yinyang ['] manji ;
: 3line ( xxx-) 3 0 DO is pic line 2 spaces LOOP ;
: 3draw ( -) hgt 0 DO i to r cr 3pic 3line LOOP ;
3draw
 

XCBQaWN0dXJlIHdvcmRzIGdpdmUgYSBmbGFnIGJhc2VkIG9uIHggYW5kIHkuCjAgVmFsdWUgeCAgMCBWYWx1ZSB5ICBcIDEwMDAweCBmaXhlZCBkZWNpbWFsLgoKOiBmcm9tICggbm4tbikgc3dhcCAtIDsKOiBzcSAoIG4tbikgZHVwIDEwMDAwICovIDsKOiBkaXNjICggcnh5LWYpIHkgZnJvbSBzcSBzd2FwIHggZnJvbSBzcSArID4gOwo6IHVkaXNjICggLWYpIDEwMDAwIDAgMCBkaXNjIDsKCjogdmVydCAoIC1mKSB4IC0xNTAwIC02MDAwIHdpdGhpbiA7CjogaG9yeiAoIC1mKSB5IC0yMDAwIC00MDAwIHdpdGhpbiA7Cjogc21hc2ggKCAtZikgdWRpc2MgdmVydCBhbmQgaG9yeiBhbmQgOwoKOiBwYWlyICggci1mZikgZHVwIDAgNTAwMCBkaXNjIHN3YXAgMCAtNTAwMCBkaXNjIDsKOiB3YXZlICggLWYpIDI1MDAgcGFpciBpbnZlcnQgeCAwPCBhbmQgb3IgOwo6IGV5ZXMgKCAtZikgMjc4IHBhaXIgb3IgOwo6IHlpbnlhbmcgKCAtZikgdWRpc2Mgd2F2ZSB4b3IgZXllcyB4b3IgOwoKOiBwaXQgKCAtZikgeCA3MTQzIDE0Mjkgd2l0aGluIHkgMTQyOSA8IG9yIDsKOiBwaXQrICggZi1mKSBwaXQgYW5kICB4IG5lZ2F0ZSB5IHRvIHggdG8geSA7CjogbWFuamkgKCAtZikgdHJ1ZSBwaXQrIHBpdCsgcGl0KyBwaXQrIDsKCgpcIEVtaXQgVVRGLTggZm9yIEJyYWlsbGUgVSsyOFhYLCBnaXZlbiBYWC4KOiBlbWl0YjggKCBjLSkgP2R1cC0wPS1JRiAkODAgVEhFTiAgJEUyIGVtaXQKICBkdXAgNiByc2hpZnQgJEEwIG9yIGVtaXQgICQzRiBhbmQgJDgwIG9yIGVtaXQgOwoKOiB+IGMsIDsgICAgIFwgRG90IHJvdy9jb2wgcGVyIEJyYWlsbGUgYml0OiAgMCAzCjogQ1ZhbHMgKCAtO2ktYykgQ3JlYXRlIGRvZXM+ICsgY0AgOyAgICAgIFwgIDEgNApDVmFscyBkciAwIH4gMSB+IDIgfiAwIH4gMSB+IDIgfiAzIH4gMyB+ICBcICAyIDUKQ1ZhbHMgZGMgMCB+IDAgfiAwIH4gMSB+IDEgfiAxIH4gMCB+IDEgfiAgXCAgNiA3CgpcIFNjcmVlbiByb3cvY29sL2RvdCB0byBwaWMgeC95LCAtMTAwMDAgdG8gMTAwMDAuCjAgVmFsdWUgciAgMCBWYWx1ZSBjICAwIFZhbHVlIGQgIERlZmVyIHBpYyAoIC1mKQoxMiBkdXAgQ29uc3RhbnQgaGd0ICAyKiBDb25zdGFudCB3aWQKOiB0b3kgKCAtKSByIDQgKiBkIGRyICsgLTUwMDAgaGd0ICovIDEwMDAwICsgdG8geSA7CjogdG94ICggLSkgYyAyICogZCBkYyArIDEwMDAwIHdpZCAqLyAxMDAwMCAtIHRvIHggOwo6IGRvdGJpdCAoIC1jKSB0b3kgdG94IHBpYyAxIGFuZCBkIGxzaGlmdCA7CjogY2FsY2I4ICggLWMpIDAgOCAwIERPIGkgdG8gZCBkb3RiaXQgb3IgTE9PUCA7CjogbGluZSAoIC0pIHdpZCAwIERPIGkgdG8gYyBjYWxjYjggZW1pdGI4IExPT1AgOwo6IGRyYXcgKCAtKSBoZ3QgMCBETyBpIHRvIHIgY3IgbGluZSBMT09QIDsKXCAnIHNtYXNoIGlzIHBpYyBkcmF3Cgo6IDNwaWMgKCAteHh4KSBbJ10gc21hc2ggWyddIHlpbnlhbmcgWyddIG1hbmppIDsKOiAzbGluZSAoIHh4eC0pIDMgMCBETyBpcyBwaWMgbGluZSAyIHNwYWNlcyBMT09QIDsKOiAzZHJhdyAoIC0pIGhndCAwIERPIGkgdG8gciBjciAzcGljIDNsaW5lIExPT1AgOwozZHJhdwo=